北京大学Julia语言入门讲义第12章： Makie包作图

using CairoMakie
CairoMakie.activate!()

学生身高体重年龄

设当前工作目录有class19.csv文件内容如下：

name,sex,age,height,weight
Sandy,F,11,130,23
Karen,F,12,143,35
Kathy,F,12,152,38
Alice,F,13,144,38
Becka,F,13,166,44
Tammy,F,14,160,46
Gail,F,14,163,41
Sharon,F,15,159,51
Mary,F,15,169,51
Thomas,M,11,146,39
James,M,12,146,38
John,M,12,150,45
Robert,M,12,165,58
Jeffrey,M,13,159,38
Duke,M,14,161,46
Alfred,M,14,175,51
William,M,15,169,51
Guido,M,15,170,60
Philip,M,16,183,68

读入为数据框：

using DataFrames, DataFramesMeta, CSV
using CategoricalArrays

dclass = CSV.read("class19.csv", DataFrame)
transform!(dclass,
    :sex => (s -> categorical(s)),
    renamecols = false)
transform!(dclass, :sex => (x -> levelcode.(x)) => :sexi,
    :age => categorical => :agec)

Cleveland心脏病数据

这是UCI网站的一个机器学习用样例数据，
关注的因变量是num，是一个取0,1,2,3,4数值的变量，
需要区分0与非0。
变量有：

• age
• sex，1为男，0为女
• cp, 胸痛类型：
  • 1：典型心绞痛
  • 2：非典型心绞痛
  • 3：非心绞痛类型
  • 4：无症状
• trestbps: 收缩压
• chol: 胆固醇
• fbs: 快速血糖是否超标，1为超标，否则0
• restecg：心电图，
  • 0: 正常
  • 1: T-ST波异常
  • 2: 提示心室肥大
• thalach: 最大心率
• exang: 是否锻炼引发心绞痛，1有，0无
• oldpeak: 锻炼引发的ST波降幅
• slope: 锻炼ST波峰斜率，
  • 1: 向上
  • 2：平缓
  • 3: 向下
• ca: 造影检查显示大血管数，取0,1,2,3
• thal:
  • 3: 正常
  • 6：固化缺陷
  • 7: 可恢复缺陷
• num: 0表示不诊断心脏病，
  1,2,3表示血管造影诊断有心脏病，
  主要血管50%以上狭窄

using Downloads
urlf = "https://archive.ics.uci.edu/ml/machine-learning-databases/heart-disease/processed.cleveland.data"
dht = CSV.read(Downloads.download(urlf), DataFrame,
    header=0)
rename!(dht, ["age", "sex", "cp", "trestbps", "chol", 
    "fbs", "restecg", "thalach", "exang", "oldpeak",    
    "slope", "ca", "thal", "num"])

303×14 DataFrame
 Row │ age      sex      cp       trestbps  chol     fbs      restecg  th ⋯     │ Float64  Float64  Float64  Float64   Float64  Float64  Float64  Fl ⋯─────┼─────────────────────────────────────────────────────────────────────   1 │    63.0      1.0      1.0     145.0    233.0      1.0      2.0     ⋯   2 │    67.0      1.0      4.0     160.0    286.0      0.0      2.0      
   3 │    67.0      1.0      4.0     120.0    229.0      0.0      2.0      
   4 │    37.0      1.0      3.0     130.0    250.0      0.0      0.0      
  ⋮  │    ⋮        ⋮        ⋮        ⋮         ⋮        ⋮        ⋮        ⋱ 300 │    68.0      1.0      4.0     144.0    193.0      1.0      0.0     ⋯ 301 │    57.0      1.0      4.0     130.0    131.0      0.0      0.0      
 302 │    57.0      0.0      2.0     130.0    236.0      0.0      2.0      
 303 │    38.0      1.0      3.0     138.0    175.0      0.0      0.0      
                                             7 columns and 295 rows omitted

dline01 = DataFrame(
    x = 1:5,
    y = [11, 13, 18, 15, 14])

5 rows × 2 columns

dline02 = DataFrame(x = [0,1,3,6,7,8], y=[15, 13, 14, 11, 10, 9])

6 rows × 2 columns

lines(dline01[:, :x], dline01[:, :y])

scatter(dline01[:, :x], dline01[:, :y])

scatterlines(dline01[:, :x], dline01[:, :y])

hist(dclass[:, :height], bins=6)

hist(dht[:,:trestbps], bins=15)

density(dclass[:, :height])

using CairoMakie: density
density(dht[:, :trestbps])

boxplot(fill(1, nrow(dclass)), dclass[:, :height])

boxplot(levelcode.(dclass[:, :sex]), dclass[:, :height])

boxplot(fill(1, nrow(dht)), dht[:, :trestbps])

boxplot(dht[:, :sex], dht[:, :trestbps])

qqnorm(dclass[:, :height], qqline=:fit)

qqnorm(dht[:, :trestbps], qqline=:fit)

ecdfplot(dht[:, :trestbps])

df = DataFrame(time=1:10, y = (1:10) .^2)
lines(df[:,:time], df[:,:y])

function surfd()
    n = 100
    xs = range(-pi, pi, n)
    ys = range(-pi, pi, n)
    z = [exp(-0.5*((x + 1)^2 + 0.5*y^2))*cos(4*x) +
        exp(-0.8*(2*x^2 + (y-1)^2))*cos(2*y)
        for x in xs, y in ys]
    return (xs, ys, z)
end
x, y, z = surfd()

contour(x, y, z, levels=20)

x, y, z = surfd()
fig, ax, plt = contourf(x, y, z, levels=20)
Colorbar(fig[1,2], plt)
fig

x, y, z = surfd()
heatmap(x, y, z)

using StatsBase
function freq(x)
    y = StatsBase.countmap(x)
    kk = [k for (k, v) in y]
    vv = [v for (k, v) in y]
    return kk, vv
end

cat2string = x -> levels(x)[levelcode.(x)]

sex, n = freq(cat2string(dclass[:, :sex]))
barplot(1:2, n,
    axis=(; width=100, height=200,
        xticks=(1:2, sex) ))

using CairoMakie
CairoMakie.activate!()

fig = Figure(backgroundcolor=:gray, 
    resolution = (800, 300))

ax = Axis(fig[1,1],
    title = "这是标题",
    xlabel = "x",
    ylabel = "y")

using CairoMakie
CairoMakie.activate!()

fig = Figure(backgroundcolor=:gray, 
    resolution = (800, 600))
ax = Axis(fig[1,1],
    title = "简单的折线图示例",
    xlabel = "x",
    ylabel = "y")
lines!(ax, dline01[:,:x], dline01[:,:y])
display(fig)

using Colors

fig = Figure()
ax = Axis(fig[1,1],
    title = "设置颜色的折线图示例",
    xlabel = "x",
    ylabel = "y")
lines!(ax, dline01[:,:x], dline01[:,:y],
    color = :green)
display(fig)

fig = Figure()
ax = Axis(fig[1,1],
    title = "简单的散点图示例",
    xlabel = "x",
    ylabel = "y")
scatter!(ax, dline01[:,:x], dline01[:,:y])
display(fig)

fig = Figure()
ax = Axis(fig[1,1],
    title = "散点图设置示例",
    xlabel = "x",
    ylabel = "y") 
scatter!(ax, dline01[:,:x], dline01[:,:y],
    color = :purple, marker = :utriangle, markersize=20)
display(fig)

fig = Figure()
ax = Axis(fig[1,1])
scatter!(dline01[:,:x], dline01[:,:y])
display(fig)

fig = Figure()
ax = Axis(fig[1,1],
    title = "散点图和折线图叠加示例",
    xlabel = "x",
    ylabel = "y")
scatter!(ax, dline01[:,:x], dline01[:,:y])
lines!(ax, dline02[:,:x], dline02[:,:y], color=:red)
display(fig)

fig = Figure()
ax = Axis(fig[1,1],
    title = "散点图和折线图叠加示例",
    xlabel = "x",
    ylabel = "y")
scatter!(ax, dline01[:,:x], dline01[:,:y], label="Data A")
lines!(ax, dline02[:,:x], dline02[:,:y], color=:red, label="Data B")
axislegend(ax)
display(fig)

fig = Figure()
ax = Axis(fig[1,1],
    title = "散点图分别设置示例",
    xlabel = "x",
    ylabel = "y") 
scatter!(ax, dline01[:,:x], dline01[:,:y],
    markersize=dline01[:,:x] .*2 .+ 10,
    color = range(0, 1, length=nrow(dline01)), 
    colormap = :thermal)
display(fig)

lines(dline01[:,:x], dline01[:,:y])

fig, ax, plt = lines(dline01[:,:x], dline01[:,:y])

fig, ax, plt = scatter(args...; kwargs)

ax, plt = scatter(gridposition, args...; kwargs)

scatter(gridposition, args...; kwargs)

scatter!(args...; kwargs...) # 使用当前默认坐标系统
scatter!(figure, args...; kwargs...) # 使用指定画布的[1,1]位置
scatter!(gridposition, args...; kwargs...) # 使用指定布局小块或子布局块
scatter!(axis, args...; kwargs...) # 使用指定坐标系统
scatter!(scene, args...; kwargs...) # 使用指定场景

plt = scatter!(args...; kwargs...)

fig = Figure(backgroundcolor = :gray80,
    resolution = (400, 300))
ax = Axis(fig[1,1], title = "测试标题")
plt = scatter!(dline01[:,:x], dline01[:,:y], label="散点图")
fig

scatter(dline01[:,:x], dline01[:,:y], 
    figure = (; backgroundcolor=:gray80, resolution=(400,300)))

scatter(dline01[:,:x], dline01[:,:y], 
    figure = (; backgroundcolor=:gray80, resolution=(400,300)),
    axis = (; title="标题", xticks = 1:5))

fig, ax, plt = scatter(dline01[:,:x], dline01[:,:y])
plt.attributes

颜色

Colors包定义了许多颜色名称，
参见:

• https://juliagraphics.github.io/Colors.jl/stable/namedcolors/

ColorThemes包提供了许多调色盘，
其中的符号如:viridis, :heat可以用作调色盘参数colormap的值，
参见：

• https://makie.juliaplots.org/stable/documentation/colors/

程序如：

let
    xs = range(-pi, pi, 100)
    ys = range(-pi, pi, 100)
    z = [exp(-0.1*(x^2 + y^2))*(cos(x) + sin(y)) 
        for x in xs, y in ys]
    fig = Figure()
    ax = Axis(fig[1,1])
    p = contourf!(ax, z, colormap = :heat)
    Colorbar(fig[1,2], p)
    display(fig)
end

又如：

let
    x = -2:0.1:2
    y = 10 .- x .^2
    lines(x, y, colormap = :Blues, color = y)
end

colormap的值可以增加一个透明度，
如colormap = (:heat, 0.5)，
这里0.5是透明度，
越小越透明。

可以用cgrad函数从给定的若干个颜色生成渐变色，
用作colormap参数的值。

可以用categorical_colors(:Blues, 3)从ColorThemes包给出的用符号表示的调色盘生成指定个数的颜色，如：

colors = categorical_colors(:Blues, 3)
fig = Figure()
ax = Axis(fig[1,1])
scatter!(rand(3), rand(3), label="a", color = colors[2])
scatter!(rand(3), rand(3), label="b", color = colors[3])
axislegend()
fig

颜色也可以增加透明度参数，如color = (:red, 0.2)。

自定义

可以用set_theme!(...)函数设置一批公用的的属性，称为主题，
其中关于绘图板的属性直接作为关键字参数输入，
关于坐标系统的选项用命名元组输入到Axis参数中。
关于图例的选项用命名元组输入到Legend参数中。
最后用没有自变量的settheme!()取消这个主题的作用。

如：

set_theme!(; backgroundcolor=:gray80, resolution=(400,300),
    Axis = (; xtickgridvisible=true, ytickgridvisible=true,
        xgridstyle=:dot, ygridstyle=:dot),
    Legend = (; bgcolor = (:green, 0.2), framecolor=:yellow))
fig, ax, plt = scatter(dline01[:,:x], dline01[:,:y], label="数据A")
scatter!(dline02[:,:x], dline02[:,:y], label="数据B")
axislegend()
set_theme!()
fig

上面程序中bgcolor = (:green, 0.2)中的0.2是颜色透明度的设置，
数值越小越透明。

可以用pallette中的color设置主题所用的调色盘，
这在多个图层重复时自动循环使用。
如：

set_theme!(; palette = (; color = [:green, :cyan]) )
fig, ax, plt = scatter(dline01[:,:x], dline01[:,:y], label="数据A")
scatter!(dline02[:,:x], dline02[:,:y], label="数据B")
axislegend()
set_theme!()
fig

内置主题

有一些内置的主题可用，
如theme_ggplot2(), theme_minimal(),
theme_black(), theme_light(), theme_dark()。
上图改用theme_black()的效果：

set_theme!( theme_black() )
fig, ax, plt = scatter(dline01[:,:x], dline01[:,:y], label="数据A")
scatter!(dline02[:,:x], dline02[:,:y], label="数据B")
axislegend()
set_theme!()
fig

调用主题

用settheme!函数自定义或调用内置主题是使用主题的一种方法，
使用内置主题时也可以用关键字参数修改某一具体设置参数。
使用不带参数的settheme!()取消这样的主题选择。

还可以用with_theme(自定义绘图函数, 主题)的格式调用主题。

另一种方法是

with_theme(主题函数()) do
    ...
end

也可以编写自己的主题函数，从略。

设置循环(cycle)

同一坐标系统有多个散点或者折线图层时，
将自动循环使用颜色。
颜色可以用主题的palette中的color参数设置一个颜色名的向量，
还可以用categorical_colors(调色盘, n)从Colors包的某个调色盘生成n个颜色。

如：

let
    x = 1:10;  y = 2 .* x
    fig = Figure(); ax = Axis(fig[1,1])
    for off in 1:10
        lines!(ax, x, y .+ off, label = "Line $(off)")
    end
    fig
end

这使用了默认的主题和默认的调色盘，
有7个不重复的颜色。

人为指定三个颜色组成的调色盘：

let
    x = 1:10;  y = 2 .* x
    fig = Figure(palette = (; color = [:red, :blue, :green]))
    ax = Axis(fig[1,1])
    for off in 1:10
        lines!(ax, x, y .+ off, label = "Line $(off)")
    end
    fig
end

上面的程序在Figure()中定义了palette，
也可以在settheme!()函数中定义。

使用categorical_colors的例子：

let
    x = 1:10;  y = 2 .* x
    set_theme!(palette = (; color = categorical_colors(:PRGn, 10)))
    fig = Figure()
    ax = Axis(fig[1,1])
    for off in 1:10
        lines!(ax, x, y .+ off, label = "Line $(off)")
    end
    set_theme!()
    fig
end

前几个例子中，
只循环利用了颜色，
没有循环利用线型、粗细等因素。
可以在set_theme!中中定义cycle参数，
要求哪些因素参与这种循环利用。
比如，cycle = Cycle([:color, :linestyle])规定先循环利用所有的颜色，
然后再使用下一种线型。

set_theme!的palette参数，
除了可以用color指定一个调色盘，
还可以用marker指定可选的散点形状，
用linestyle指定可选的线型。

循环颜色与线型的程序如：

let
    x = 1:10;  y = 2 .* x
    set_theme!(palette = (; color = categorical_colors(:Accent_3, 3)),
        Lines = (; cycle = Cycle([:color, :linestyle])))
    fig = Figure()
    ax = Axis(fig[1,1])
    for off in 1:10
        lines!(ax, x, y .+ off, label = "Line $(off)")
    end
    set_theme!()
    fig
end

对于散点图，
可重复利用的包括颜色、散点形状，
在set_theme!中写法如Scatter = (; cycle = Cycle([:color, :marker]))。

这样的写法是将颜色轮流用一遍后才修改第二种元素，
还可以让这些元素并行地循环使用，这时在Cycle()中加covary=true选项，
如：

let
    x = 1:10;  y = 2 .* x
    set_theme!(palette = (; color = categorical_colors(:Accent_3, 3)),
        Lines = (; cycle = Cycle([:color, :linestyle], covary=true)))
    fig = Figure()
    ax = Axis(fig[1,1])
    for off in 1:10
        lines!(ax, x, y .+ off, label = "Line $(off)")
    end
    set_theme!()
    fig
end

标题

在Axis()函数中可以用title设置标题，
用subtitle设置子标题（在标题下面一行），
用xlabel设置x轴标签，
用ylabel设置y轴标签。

可以用titlealign指定标题和小标题的对齐方式，
如:left, :right。
可以用titlecolor指定标题颜色，
用titlefont指定标题字体，
用titlesize指定标题字体大小（像素）。
小标题也可以使用用类似选项。
可以用titlegap指定标题与小标题之间的间隙（像素）。

如：

fig = Figure()
ax = Axis(fig[1,1],
    title = "简单的折线图示例",
    subtitle = "使用Axis()设置",
    titlesize = 30, subtitlesize = 15,
    titlecolor=:green, subtitlecolor=:pink)
lines!(ax, dline01[:,:x], dline01[:,:y])
xlims!(ax, [0, 10])
display(fig)

坐标轴范围

可以用xlims!()设置x轴范围，如：

fig = Figure()
ax = Axis(fig[1,1],
    title = "简单的折线图示例",
    xlabel = "x",
    ylabel = "y")
lines!(ax, dline01[:,:x], dline01[:,:y])
xlims!(ax, [0, 10])
display(fig)

也可以写成xlims!(ax, 0, 10)。
如果写成xlims!(ax, 10, 0)，则x轴会逆转过来：

xlims!(ax, 10, 0)
display(fig)

对y轴可以类似地使用ylims!()调整范围。
对x、y可以同时设置limits!(ax, x1, x2, y1, y2)。

如果范围下限或者上限设置为nothing则自动确定。
如xlims!(ax, 0, nothing)自动设置上限。
也可以用关键字low指定下限，
关键字high指定上限。

可以在Axis()中指定x轴和y轴的上下限如Axis(fig[1,1], limits=(;x1,x2,y1,y2))，
其中的x1, x2, y1, y2都可以取nothing表示自动获取。如：

fig = Figure()
ax = Axis(fig[1,1], limits = (nothing, 10, nothing, nothing))
lines!(ax, dline01[:,:x], dline01[:,:y])
display(fig)

刻度

在Axis()中用xticks设置x轴刻度，
用yticks设置y轴刻度。

直接设置刻度线所在数值组成的向量，如：

fig = Figure()
ax = Axis(fig[1,1], xticks = 0:2:10)
lines!(ax, dline01[:,:x], dline01[:,:y])
display(fig)

并没有达到我们的目的。
这是因为坐标轴刻度有一些内部算法，
程序输入的要求仅作为目标。
配合xlims!：

fig = Figure()
ax = Axis(fig[1,1], xticks = 0:2:10)
lines!(ax, dline01[:,:x], dline01[:,:y])
xlims!(ax, 0, 10)
display(fig)

xticks的值也可以写成[0, 2, 4, 6, 8, 10]这样的向量值。
也可以指定标签：

fig = Figure()
ax = Axis(fig[1,1], xticks = (0:2:6, ["t0", "t2", "t4", "t6"]))
lines!(ax, dline01[:,:x], dline01[:,:y])
xlims!(ax, 0, 6)
display(fig)

可以用WilkinsonTicks(n)表示有n个刻度，
如：

fig = Figure()
ax = Axis(fig[1,1], xticks = WilkinsonTicks(4))
lines!(ax, dline01[:,:x], dline01[:,:y])
xlims!(ax, 0, 6)
display(fig)

因为常用各种等间隔刻度，
所以提供了MultiplesTicks()函数用来指定特殊间隔的刻度，如：

let
    da = DataFrame(x = 0:0.1:(4*pi))
    transform!(da, :x => ByRow(sin) => :y)
    fig = Figure()
    ax = Axis(fig[1,1], xticks = MultiplesTicks(5, pi, "π"))
    lines!(ax, da[:,:x], da[:,:y])
    fig
end

可以在Axis()中用xtickformat参数指定一个函数，
该函数输入刻度值向量，
返回显示字符串向量。
ytickformat类似。
如：

fig = Figure()
ax = Axis(fig[1,1], xtickformat = (s -> string.(s) .* "E3"))
lines!(ax, dline01[:,:x], dline01[:,:y])
xlims!(ax, 0, 6)
display(fig)

xtickformat还可以指定一个格式字符串，其中可以用如{:.2f}这样的方法指定一个刻度值的输出格式，
也可以有其他原样内容。如：

fig = Figure()
ax = Axis(fig[1,1], xtickformat = "x = {:.2f}")
lines!(ax, dline01[:,:x], dline01[:,:y])
display(fig)

可以用xticklabelrotation指定一个数值使得x轴刻度值逆时针旋转指定的弧度数。
如：

fig = Figure()
ax = Axis(fig[1,1], xtickformat = "x = {:.2f}",
    xticklabelrotation = pi/6)
lines!(ax, dline01[:,:x], dline01[:,:y])
display(fig)

网格线

二维图一般只在下方显示x轴，
左侧显示y轴。
可以在Axis()中加xticksmirrored=true使得上侧也显示刻度线，
用xgridvisible=true使得x轴刻度包括网格线，
还可以加xminorticksvisible=true显示细刻度，
加xminorgridvisible=true显示细刻度网格线。
需要细刻度时，指定xminorticks=IntervalsBetween(n)表示两个粗刻度之间用细刻度等分为n段。
y轴类似。

fig = Figure()
ax = Axis(fig[1,1],  
    xticksmirrored = true,
    yticksmirrored = true, 
    xgridvisible=true,
    ygridvisible=true)
lines!(ax, dline01[:,:x], dline01[:,:y])
xlims!(ax, 0, 6)
display(fig)

对某个坐标系统ax，
可以用hidespines!(ax)令其不显示坐标轴。
可以用hidexdecorations!(ax)令其不显示刻度线、刻度值、网格线。

对数坐标轴

在Axis()中设yscale = log10可以对y轴使用对数轴。x轴类似。
可取的值包括identity(缺省值), log10, log2, log, sqrt, Makie.logit。

宽高比

坐标系统属性aspect用来控制宽高比。
如果不控制宽高比，
正圆可能会变成椭圆：

let
    th = 0:0.1:(2*pi)
    x = cos.(th)
    x = [x; x[1]]
    y = sin.(th)
    y = [y; y[1]]
    da = DataFrame(x=x, y=y)
    lines(da[:,:x], da[:,:y])
end

用坐标系统选项aspect=1控制宽高比为

1:1：

let
    th = 0:0.1:(2*pi)
    x = cos.(th)
    x = [x; x[1]]
    y = sin.(th)
    y = [y; y[1]]
    da = DataFrame(x=x, y=y)
    lines(da[:,:x], da[:,:y],
        axis = (; aspect = 1))
end

第二纵轴

可以用xaxisposition=:top将x轴画在上方，
用yaxisposition=:right将y轴画在右侧。

可以将两个坐标系统指定在绘图板的同一个格子中，
然后隐藏第二个坐标系统的坐标轴和x轴刻度、标签，设置y轴在右侧，
在两个坐标系统中分别制作一个图层，
就可以实现左右双侧纵轴。

fig = Figure()
ax = Axis(fig[1,1],
    title = "散点图和折线图叠加示例",
    xlabel = "x",
    ylabel = "y")
scatter!(ax, dline01[:,:x], dline01[:,:y],
    label = "数据集A")
lines!(ax, dline02[:,:x], dline02[:,:y], color = :red,
    label = "数据集B")
axislegend(ax)
display(fig)

fig = Figure()
ax = Axis(fig[1,1],
    title = "散点图和折线图叠加示例",
    xlabel = "x",
    ylabel = "y")
scatter!(ax, dline01[:,:x], dline01[:,:y],
    marker = :utriangle, label = "数据集A")
lines!(ax, dline02[:,:x], dline02[:,:y], 
    color = :red, linestyle = :dot, label = "数据集B")
axislegend(ax)
display(fig)

fig = Figure()
ax1 = Axis(fig[1, 1:2],
    xlabel="height", ylabel="weight")
ax2 = Axis(fig[1, 3],
    xlabel="age", ylabel="weight")
ax3 = Axis(fig[2, 1:3],
    xlabel="height")
fig

scatter!(ax1, dclass[:, :height], dclass[:, :weight])
scatter!(ax2, dclass[:,:age], dclass[:,:weight])
hist!(ax3, dclass[:, :height])
display(fig)

fig = Figure()
ax = Axis(fig[1,1],
    title = "散点图和折线图叠加示例",
    xlabel = "x",
    ylabel = "y")
scatter!(ax, dline01[:,:x], dline01[:,:y],
    marker = :utriangle, label = "数据集A")
lines!(ax, dline02[:,:x], dline02[:,:y], 
    color = :red, linestyle = :dot, label = "数据集B")
Legend(fig[1,2], ax)
display(fig)

let
    xs = range(-pi, pi, 100)
    ys = range(-pi, pi, 100)
    z = [exp(-0.1*(x^2 + y^2))*(cos(x) + sin(y)) 
        for x in xs, y in ys]
    fig = Figure()
    ax = Axis(fig[1,1])
    p = contourf!(ax, z)
    Colorbar(fig[1,2], p)
    display(fig)
end

let
    x = 0:0.01:4
    f = x -> exp(-0.2*x) * cos(2*pi*x)
    y = f.(x)
    fig, ax, plt = lines(x, y, 
        label = L"e^{-0.2 x} \cos(2 \pi x)")
    text!(L"f(x) = e^x; \quad  g(x) = \cos x", position = (1.5, 0.9))
    axislegend()
    fig
end

fig = Figure(resolution = (1000, 700))
ga = fig[1,1] = GridLayout()
gb = fig[2,1] = GridLayout()
gcd = fig[1:2, 2] = GridLayout() # 其中再嵌入方格摆放层
gc = gcd[1,1] = GridLayout()
gd = gcd[2,1] = GridLayout();

axa1 = Axis(ga[1,1])
axa2 = Axis(ga[2,1])
axa3 = Axis(ga[2,2])

let
    sex, n1 = freq(dht[:, :sex])
    barplot!(axa1, sex, n1)
    
    cp, n2 = freq(dht[:, :cp])
    barplot!(axa2, cp, n2)

    restecg, n3 = freq(dht[:, :restecg])
    barplot!(axa3, restecg, n3)
end
fig

axb = Axis(gb[1,1])
boxplot!(axb, dht[:,:sex], dht[:,:thalach])
fig

axc = Axis(gc[1,1])
scatter!(axc, dht[:,:age], dht[:,:thalach])
fig

axd = Axis(gd[1,1])
hist!(axd, dht[:,:thalach])
fig

colsize!(fig.layout, 1, Auto(0.5))
rowsize!(gcd, 1, Auto(1.5))
fig

colsize!(fig.layout, 1, Fixed(200))

colsize!(fig.layout, 1, Relative(1/3))

colgap!(fig.layout, 1, Relative(0.1))

fig = Figure()
ax1 = Axis(fig[1,1])
ax2 = Axis(fig[1,2])
scatter!(ax1, dht[:, :thalach], dht[:,:trestbps])
Label(fig[1,1,TopLeft()], "(a)")
Label(fig[1,1,Right()], "血压对最大心律", rotation = pi/2)
boxplot!(ax2, fill(1, nrow(dht)), dht[:,:trestbps])
Label(fig[1,2,TopLeft()], "(b)")
fig

let
    xs = 0:0.1:2*pi
    ys = sin.(xs)
    points = collect(zip(xs, ys))
    scatter(points)
end

let
    xs = 0:0.1:2*pi
    ys = sin.(xs)
    points = Point2f.(xs,ys)
    scatter(points)
end

let
    xs = 0:0.1:2*pi
    ys = sin.(xs)
    points = Point2f.(xs,ys)
    scatter(points, color=1:length(points), colormap=:thermal)
end

let
    fig = Figure()
    ax = Axis(fig[1,1])
    scatter!(ax, rand(10), rand(10), label="数据1")
    scatter!(ax, rand(10), rand(10), label="数据2")
    axislegend(ax)
    fig
end

散点符号参考

Makie的散点符号来自TeX Gyre Heros Makie字体，
可以直接使用unicode字符，
也有一些符号可以用Symbol类型访问。

许多中文输入法有输入字符的功能。
下面的例子展示了许多特殊字符：

let
    marker_str = "☆○◇□△▽◁▷♡★●◆■▲▼◀▶↖↑↗←→↙↓↘√×❤⊙⊕※▬〓§Ψ☢"
    markers = collect(marker_str)
    fig = Figure()
    ax = Axis(fig[1, 1], yreversed = true,
        xautolimitmargin = (0.15, 0.15),
        yautolimitmargin = (0.15, 0.15)
    )
    hidedecorations!(ax)

    for (i, marker) in enumerate(markers)
        p = Point2f(fldmod1(i, 6)...)

        scatter!(p, marker = marker, markersize = 20, color = :black)
    end

    fig
end

使用如：

scatter(rand(10), rand(10), marker='■', markersize=20)

注意要使用字符'■'，
而不是字符串"■"。

下面的例子给出了多个符号名表示的散点符号：

using CairoMakie

markers_labels = [
    (:rect, ":rect"),
    (:star5, ":star5"),
    (:diamond, ":diamond"),
    (:hexagon, ":hexagon"),
    (:cross, ":cross"),
    (:xcross, ":xcross"),
    (:utriangle, ":utriangle"),
    (:dtriangle, ":dtriangle"),
    (:ltriangle, ":ltriangle"),
    (:rtriangle, ":rtriangle"),
    (:pentagon, ":pentagon"),
    (:star4, ":star4"),
    (:star8, ":star8"),
    (:vline, ":vline"),
    (:hline, ":hline"),
    (:x, ":x"),
    (:+, ":+"),
    (:circle, ":circle"),
    ('a', "'a'"),
    ('B', "'B'"),
    ('↑', "'\\uparrow'"),
    ('😄', "'\\:smile:'"),
    ('✈', "'\\:airplane:'"),
]

f = Figure()
ax = Axis(f[1, 1], yreversed = true,
    xautolimitmargin = (0.15, 0.15),
    yautolimitmargin = (0.15, 0.15)
)
hidedecorations!(ax)

for (i, (marker, label)) in enumerate(markers_labels)
    p = Point2f(fldmod1(i, 6)...)

    scatter!(p, marker = marker, markersize = 20, color = :black)
    text!(p, text = label, color = :gray70, offset = (0, 20),
        align = (:center, :bottom))
end

f

用法如：

scatter(rand(10), rand(10), marker=:rect, markersize=20)

也可以将marker参数输入为一个向量，
给每个散点分别指定符号；
可以将markersize参数输入为一个向量，
给每个散点分别指定大小（单位是像素）。

let
    x, y, z = surfd()
    heatmap(x, y, z)
end

分组变量条形图

set_aog_theme!()
p1 = data(dht) * mapping(:cp) * frequency()
draw(p1, axis = (width = 200, height = 400))

变量cp为胸痛类型：

1. 典型心绞痛
2. 非典型心绞痛
3. 非心绞痛类型
4. 无症状

AlgebraOfGraphics包用*号连接互相补充的设定。

如果希望将图形输出为PNG文件，可将上述程序最后一行改成：

fig = draw(p1; axis = (width = 200, height = 400))
save("barplot-ex.png", fig, px_per_unit=3)

其中关键字参数px_per_unit用来指定一个放大倍数，
可以省略。

可以将条形按性别分段，
用不同颜色代表性别：

p1b = p1 *
    mapping(color = :sex => nonnumeric, stack = :sex => nonnumeric)
draw(p1b, axis = (width = 200, height = 400))

颜色、分组需要使用类别变量。
0表示女性，1表示男性。

并列格式的条形图：

p1c = p1 *
    mapping(color = :sex => nonnumeric, 
    dodge = :sex => nonnumeric)
draw(p1c, axis = (width = 200, height = 400))

散点图

最大心律对年龄的散点图：

p1 = data(dht) * mapping(:age, :thalach)
draw(p1)

AlgebraOfGraphics用用+使两个图层，
两个图层仅共享同一坐标系。
在散点图上面再添加一个拟合线图层：

p1b = p1 + p1 * linear()
draw(p1b)

增加一个颜色(color)维度，
可以用不同颜色区分性别：

p1c = p1 * mapping(color = :sex => nonnumeric)
draw(p1c)

在没有明确的分组(group)维度时，
颜色维度还起到了分组的作用。

按颜色分组的散点图图层和按颜色分组的拟合线图层：

p1d = p1 * mapping(color = :sex => nonnumeric) +
    p1 * linear() * mapping(color = :sex => nonnumeric)
draw(p1d, axis = (width = 400, height = 300))

男女分别在一个切片（小图）中作图：

p1e = p1 * mapping(layout = :sex => nonnumeric)
draw(p1e, axis = (width = 300, height = 300))

p1f = (p1 + p1 * linear()) * 
    mapping(layout = :sex => nonnumeric)
draw(p1f, axis = (width = 300, height = 300))

二元密度图

考虑年龄和最大心律的二元分布密度，
可以用热力图表示。

p2 = data(dht) * mapping(:age, :thalach) * 
    AlgebraOfGraphics.density()
draw(p2, axis = (width = 300, height = 300))

作成等高线图：

p2b = p2 * visual(Contour)
draw(p2b, axis = (width = 300, height = 300))

用加号增加散点图层和拟合线图层：

p2c = p1 +
    p1 * linear() +
    p2 * visual(Contour)
draw(p2c, axis = (width = 300, height = 300))

其它维度

mapping()可以用位置参数输入条形图的变量，
输入散点图的横纵坐标变量，
其它的维度用关键字参数如：

• color 颜色
• marker 散点图案
• group 分组
• layout 切片分组
• row, col: 分组小图。

x = collect(range(0, 2π, 100))
y = sin.(x)
p1 = data((; x=x, y=y)) * mapping(:x, :y) * visual(Lines)
draw(p1)

p1 = data(dht) * mapping(:age => "年龄", :thalach => "血压")
draw(p1, axis = (width = 300, height = 300))

p1 = data(dclass) * mapping(:height => (x -> x / 100) => "身高", :weight => "体重")
draw(p1, axis = (width = 300, height = 300))

dc = copy(dclass)
DataFramesMeta.transform!(dc, 
  :height => (x -> x ./ 100) => "身高(米)")
p2 = data(dc) * mapping("身高(米)", :weight => "体重")
draw(p2, axis = (width = 300, height = 300))

简化的变换

有一些比较常用的变换，
AlgebraOfGraphics包提供了相应的函数。

对分类变量，
renamer()变换可以在mapping()中临时指定不同的标签值，
如：

p1 = data(dclass) * frequency() * mapping(
    :sex => renamer("F" => "女", "M" => "男") => "性别")
draw(p1, axis = (width = 200, height = 400))

分类变量的类别次序可以用sorter([新次序])在mapping中临时修改次序，如：

p2 = data(dclass) * frequency() * mapping(
    :sex => sorter(["M", "F"]))
draw(p2, axis = (width = 200, height = 400))

需要将数值型变量作为分类变量使用时，
可以用nonnumeric函数在mapping中临时修改其用途,
如：

p3 = data(dclass) * frequency() * 
    mapping(:age => nonnumeric)
draw(p3, axis = (width = 200, height = 400))

注意上面的nonnumeric不能写成nonnumeric()。

另外，
在mappings()中可以用:变量名 => verbatim指定该变量原样使用，
不进行任何映射（变换），
可以用来在坐标系中指定坐标位置添加文本内容，
也可以输入适当的颜色名直接指定颜色。

pv1 = data(dline01) * mapping(:x, :y)
draw(pv1 * visual(Scatter, color=:blue), axis=(width=300, height=300))

draw(pv1 * visual(Lines), axis=(width=300, height=300))

draw(pv1 * visual(ScatterLines), axis=(width=300, height=300))

pdm1 = data(dclass) * mapping(:height, :weight)
pf1 = mapping(col = :sex)
draw(pdm1 * pf1)

pdm1 = data(dclass) * mapping(:height, :weight)
pf1 = mapping(row = :sex)
draw(pdm1 * pf1)

dlay01 = DataFrame(f1 = categorical(rand(["a", "b"], 100)), 
    f2 = rand(["c", "d"], 100),
    x0 = randn(100), y0 = randn(100))
transform!(dlay01, [:y0, :f1] => ByRow((x, f) -> f == "a" ? x + 1 : x + 4) => :y,
    [:x0, :f2] => ByRow((x, f) -> f == "c" ? x + 10 : x + 20) => :x)

100 rows × 6 columns

pdm1 = data(dlay01) * mapping(:x, :y)
dlay1 = mapping(row=:f1, col=:f2)
draw(pdm1 * dlay1)

draw(pdm1 * dlay1, facet = (; linkxaxes = :minimal))

draw(pdm1 * dlay1, facet = (; linkxaxes = :none))

pdm1 = data(dclass) * mapping(:height, :weight)
pf1 = mapping(layout = :sex)
draw(pdm1 * pf1)

p1 = data(dht) * mapping(:age, :thalach, layout = :cp => nonnumeric)
draw(p1)

用histogram函数作直方图

为了对连续取值变量作直方图，
可以调用histogram()函数。如：

p1 = data(dht) * mapping(:thalach) * histogram()
draw(p1)

按性别分段：

p1b = data(dht) * mapping(:thalach, 
    color=:sex => nonnumeric, stack=:sex => nonnumeric) * histogram()
draw(p1b)

按性别切片：

d1c = data(dht) * mapping(:thalach, 
    layout=:sex => nonnumeric) * histogram()
draw(d1c)

可以在histogram()中指定一些参数，
如bins指定分组数或具体分点。

用histogram函数作二元直方图

心脏病数据集中年龄与血压的二元直方图：

p1 = data(dht) * mapping(:age, :thalach) * histogram(bins=20)
draw(p1)

用density函数作密度估计曲线

对dht中的血压作密度估计曲线：

p1 = data(dht) * mapping(:thalach) * AlgebraOfGraphics.density()
draw(p1)

用density函数作二元密度估计图

心脏病人年龄与血压的二元密度估计热力图，同于二元直方图：

p1 = data(dht) * mapping(:age, :thalach) * AlgebraOfGraphics.density(npoints = 20)
draw(p1)

可见二元密度估计图默认使用了二元直方图。
制作三维曲面图形：

p1b = p1 * visual(Surface)
draw(p1b, axis=(type=Axis3, zticks=0:0.1:0.2, 
    limits=(nothing, nothing, (0, 0.001))))

曲面图最好使用GLMakie后端，
以获得交互功能。

用frequency函数作频数条形图

当mapping中仅有一个分类变量作为位置参数时，
默认就是作频数条形图。
用frequency()可以对任何变量要求作这种图。
比如，dht中age是一个数值型变量，下面作不同年龄的频数条形图：

p1 = data(dht) * mapping(:age) * frequency()
draw(p1)

expectation函数

输入了多个位置参数后，
固定最后一个位置参数的值对前面的位置参数作图。

用linear画拟合回归直线

对体重和身高拟合回归直线，
作散点图并叠加回归直线。
回归直线自动伴随有置信区间。

p1 = data(dclass) * mapping(:height, :weight) *(
    visual(Scatter) +
    linear())
draw(p1)

这个例子用了乘法到加法的分配律。

用smooth拟合局部多项式曲线

对dclass的体重对身高散点图，
拟合局部多项式曲线：

p1 = data(dclass) * mapping(:height, :weight) *(
    visual(Scatter) +
    smooth(span=0.75) * visual(color=:red))
draw(p1)

smooth的参数span一般取为0到1之间的小数，
取值越大，得到的曲线越光滑。

文本图

指定x, y坐标和文字变量后，
可以在指定坐标显示文字内容。
文字变量需要是字符串类型。
如：

p1 = data(dclass) * 
    mapping(:name => verbatim, (:height, :weight) => Point) *
    visual(Annotations, textsize=8)
draw(p1)

注意verbatim的使用。这个变换说明前面的变量需要保持原来的值使用，
不作任何变换，
这里用来提供要标注的文本内容。

在draw中设置标题

p1 = data(dclass) * mapping(:height, :weight)
draw(p1, axis = (; width=400, height=300, title="体重对身高",
        xlabel="身高", ylabel = "体重"))

注意(; width=400, height=300)这样的写法是“有名元组”的比较规范的写法。
当只有一个元素时必须这样写，
多个元素时不是必须的， 但这样写的用意比较明确。

在draw中设置坐标轴

draw()的axis参数中还可以规定许多关于坐标系统和坐标轴的设置。
如axis = (; aspect = 1.0)规定宽高比：

p1 = data(dclass) * mapping(:sex) * frequency()
draw(p1, axis=(; aspect = 1/3))

在axis中用xticks指定x轴刻度数字序列，
yticks指定y轴刻度数字序列，
如：

p2 = data(dht) * mapping(:age, :thalach)
draw(p2, axis = (; xticks = 30:20:70))

p3 = data(dht) * mapping(:age, :thalach)
draw(p3, axis = (; xticks = (30:20:70, ["三十", "五十", "七十"])))

function cp_recode(x)
    x = string.(Int.(x))
    x = categorical(x)
    recode!(x, "1" => "典型心绞痛", "2" => "非典型心绞痛",
        "3" => "非心绞痛", "4" => "无症状")
    x
end
dht2 = transform(dht, :cp => cp_recode => :cpc)
p4 = data(dht2) * mapping(:cpc, :thalach) *
    visual(BoxPlot)
draw(p4)

上面的程序对cp变量进行了比较复杂的处理。
这是因为目前CategoricalArrays对字符串转换为分类变量支持最完善，
虽然数值也可以直接转换为字符串，
但是与AlgebraOfGraphics接口不太顺畅。
所以，写了转换函数recode_cp，
先将cp原来的浮点型转换为整型，
再转换为字符串，
再转换为因子，
并对四个水平适当命名。
因为mapping()中的变量变换都是期望逐行进行的，
而转换为因子是整列进行的，
所以额外用了transform函数生成转换后的cpc变量，
而不是在mapping()中调用recode_cp。

如果x轴本来是字符型的，
需要修改标签值，
可以在mapping()中用辅助的renamer()函数进行修改。

在draw中设置绘图板

可以用draw()的figure选项输入一个有名元组，
在有名元组中填入背景色、大小等设置。
如draw(fig, figure = (; resolution = (1000, 800)))。

例：

p1 = data(dht) * mapping(:thalach, layout = :sex => nonnumeric) *
    histogram()
draw(p1, figure = (; backgrouncolor=:gray80, figure_padding = 10, 
        resolution=(600, 300)))

其中figure_padding是整个绘图版周围边空宽度。

在draw中设置图例

绘图函数的图例是自动生成的，
可以在draw()函数中用legend参数指定一个有名元组进行图例的设置。
如：

p1 = data(dht) * mapping(:age, :thalach) * 
    mapping(color = :sex => renamer(0 => "女", 1 => "男") => "性别")
draw(p1)

上面关于不同性别使用不同颜色的图例自动标在右侧。
在draw()中用figure()进行一些修改：

draw(p1, legend = (; position = :top, titleposition = :left, 
        framevisible = true, padding = 5))

在draw中设置调色盘

在Makie中用colormap设置连续值映射到颜色的调色盘，
对于离散值如性别，
可以用color映射自动匹配颜色，
也允许在draw()中用palettes参数指定一个包含元素color的命名元组，
在color中人为指定颜色对应关系。
如：

function recode_sex(x)
    x = string.(Int.(x))
    x = categorical(x)
    recode!(x, "0" => "女", "1" => "男")
    x
end
dht2 = transform(dht, :sex => recode_sex => :sexc)
p1 = data(dht2) * mapping(:age, :thalach) * 
    mapping(color = :sexc => "性别" )
draw(p1, palettes = (; color = ["女" => :red, "男" => :blue]))

这里为了将原数据集dht中的性别(sex)转换为字符型来源的类别变量，
单独写了转换函数，
还用了transform函数，
而不是直接在mapping()函数中转换。
mapping()函数的转换有一些限制，
而且对数值转换为类别变量兼容性不好。

当需要用的颜色比较多时，
可以人为选择某种渐变色生成指定个数的颜色。
如cgrad(:cividis, 8, categorical=true)从:cividis调色盘生成8个渐变色。

在draw中设置渐变颜色条

渐变颜色条(colorbar)是将连续取值的变量映射为颜色时的一个对照图例。
可以在draw()中用colorbar参数输入一个有名元组用于设置渐变颜色条，
如position = :top可以放在顶部，
size = 25规定宽度。
为了修改数值到颜色的映射调色盘，
可以在visual()函数中用colormap参数指定一个连续颜色调色盘，
如colormap = :thermal。

例：

p1 = data(dht) * mapping(:age, :thalach) * 
    AlgebraOfGraphics.density(npoints = 20) * 
    visual(Heatmap, colormap = :heat)
draw(p1, colorbar = (; position = :top, size = 25))

其它常用调色盘如:thermal, :viridis。

let
    x = range(-2, 2, 100)
    y = x .^ 2
    d = DataFrame(x = x, y = y)
    p1 = data(d) * mapping(:x, :y) * visual(Lines)
    draw(p1, axis = (; title = L"Graph of $y = x^2$",
            xlabel="x", ylabel = L"x^2"))
end

fig = Figure(resolution=(200,400))
p1 = data(dht) * mapping(:sex) * frequency()
draw!(fig[1,1], p1)
display(fig)

fig = Figure()
p1 = data(dht) * mapping(:sex) * frequency()
draw!(fig[1,1], p1)
p2 = data(dht) * mapping(:age) * histogram()
draw!(fig[1,2], p2)
colsize!(fig.layout, 1, Auto(0.5))
fig

fig = Figure()
p1 = data(dht) * mapping(:sex) * frequency()
draw!(fig[1,1], p1)
ax2 = Axis(fig[1,2])
scatter!(ax2, dht[:,:age], dht[:,:thalach])
colsize!(fig.layout, 1, Auto(0.5))
fig

fig = Figure()
ax1 = Axis(fig[1,1])
p1 = data(dht) * mapping(:sex) * frequency()
draw!(ax1, p1)
ax2 = Axis(fig[1,2])
scatter!(ax2, dht[:,:age], dht[:,:thalach])
colsize!(fig.layout, 1, Auto(0.5))
fig

dm1 = data(dline01) * mapping(:x, :y)
lay1 = visual(Scatter)
draw(dm1 * lay1)

dm1 = data(dline01) * mapping(:x, :y)
lay1 = visual(Lines)
draw(dm1 * lay1)

dm1 = data(dline01) * mapping(:x, :y)
lay1 = visual(Scatter) + visual(Lines)
draw(dm1 * lay1)

dp1 = data(dline01) * mapping(:x, :y) * visual(Lines)
dp2 = data(dline02) * mapping(:x, :y) * visual(Lines)
draw(dp1 + dp2)

dp1 = data(dht) * mapping(:cp, :thalach) * visual(BoxPlot)
draw(dp1; axis=(width=200, height=400))

dp1 = data(dht) * mapping(:cp, :thalach) * 
    visual(BoxPlot, show_notch=true)
draw(dp1; axis=(width=200, height=400))

dp1 = data(dht) * mapping(:cp, :thalach) * visual(Violin)
draw(dp1; axis=(width=200, height=400))

dp1 = data(dht) * mapping(:cp, :thalach, 
    color = :sex => nonnumeric, side = :sex => nonnumeric) * visual(Violin)
draw(dp1; axis=(width=200, height=400))

dp1 = data(dclass) * mapping(:height) * visual(QQNorm, qqline=:fit)
draw(dp1)

dlog01 = DataFrame(x = 1:10, 
    y = [1, 1.5, 2, 3, 6, 9, 14, 20, 28, 30])
dm1 = data(dlog01) * mapping(:x, :y)
draw(dm1)

draw(dm1, axis = (;yscale=log))

dn2 = DataFrame(x = rand(100), y = rand(100), z = rand(100))

100 rows × 3 columns

p1 = data(dn2) * mapping([:x, :y, :z] .=> "三个变量") *
    AlgebraOfGraphics.density() * 
    mapping(color = dims(1) => renamer(["x", "y", "z"]))
draw(p1)

p2 = data(dn2) * mapping(:x, [:y, :z] .=> "yz") *
    visual(Scatter) *
    mapping(color = dims(1) => renamer(["y", "z"]))
draw(p2)

n = 100
dn3 = DataFrame(
    x1 = 1 .+ randn(n),
    x2 = 5 .+ randn(n),
    y1 = 10 .+ randn(n),
    y2 = 20 .+ randn(n))
p3 = data(dn3) * visual(Scatter) *
    mapping([:x1, :x2], [:y1 :y2], col = dims(1), row = dims(2))
draw(p3)

draw(p3, facet = (;linkxaxes = :all, linkyaxes = :all))

using GLMakie
GLMakie.activate!()

fig = Figure()
ax = Axis3(fig[1, 1]; aspect=(1, 1, 1), 
    perspectiveness=0.5,
    xlabel="年龄", ylabel="最大心率", zlabel="血压")
scatter!(ax, dht[:,:age], dht[:,:thalach], dht[:,:trestbps])
fig

fig = Figure()
ax = Axis3(fig[1, 1]; aspect=(1, 1, 1), 
    perspectiveness=0.5,
    xlabel="年龄", ylabel="最大心率", zlabel="血压")
meshscatter!(ax, dht[:,:age], dht[:,:thalach], dht[:,:trestbps],
    markersize = 1)
fig

let
    x, y, z = surfd()
    fig = Figure(resolution=(800, 800))
    ax = Axis3(fig[1,1], aspect=(1,1,1))
    plt = surface!(ax, x, y, z)
    fig
end

let
    x, y, z = surfd()
    fig = Figure(resolution=(800, 800))
    ax = Axis3(fig[1,1], aspect=(1,1,1))
    plt = wireframe!(ax, x, y, z)
    fig
end

let
    x, y, z = surfd()
    fig = Figure(resolution=(800, 800))
    ax = Axis3(fig[1,1], aspect=(1,1,1))
    plt = contour3d!(ax, x, y, z, levels=20)
    fig
end

let
    x, y, z = surfd()
    fig = Figure(resolution=(800, 800))
    ax = Axis(fig[1,1], aspect=DataAspect())
    plt = heatmap!(ax, x, y, z)
    Colorbar(fig[1,2], plt)
    fig
end

let
    x, y, z = surfd()
    fig = Figure(resolution=(800, 800))
    ax = Axis(fig[1,1], aspect=DataAspect())
    plt = contour!(ax, x, y, z, levels=20)
    fig
end

let
    x, y, z = surfd()
    fig = Figure(resolution=(800, 800))
    ax = Axis(fig[1,1], aspect=DataAspect())
    plt = contourf!(ax, x, y, z, levels=20)
    Colorbar(fig[1,2], plt, height=Relative(0.7))
    fig
end